prezto/themes/sorin/prompt_sorin_setup

# ------------------------------------------------------------------------------
#          FILE:  prompt_sorin_setup
#   DESCRIPTION:  oh-my-zsh theme file.
#        AUTHOR:  Sorin Ionescu <sorin.ionescu@gmail.com>
#       VERSION:  1.0.6
#    SCREENSHOT:  http://i.imgur.com/aipDQ.png
# ------------------------------------------------------------------------------
function prompt_sorin_precmd () {
  setopt NO_XTRACE NO_KSHARRAYS LOCAL_OPTIONS

  if (( $+functions[git-info] )); then
    git-info
  fi
}

function prompt_sorin_setup() {
  setopt NO_XTRACE NO_KSHARRAYS LOCAL_OPTIONS
  prompt_opts=(cr subst percent)

  autoload -Uz add-zsh-hook
  add-zsh-hook precmd prompt_sorin_precmd

  zstyle ':prompt:' vicmd '%F{yellow}❮%f%B%F{red}❮%f%b%F{red}❮%f'
  zstyle ':prompt:' completion '%B%F{red}...%f%b'
  zstyle ':git-info:' action ':%%B%F{yellow}%s%f%%b'
  zstyle ':git-info:' added ' %%B%F{green}✚%f%%b'
  zstyle ':git-info:' ahead ' %%B%F{yellow}⬆%f%%b'
  zstyle ':git-info:' behind ' %%B%F{yellow}⬇%f%%b'
  zstyle ':git-info:' branch ':%F{red}%b%f'
  zstyle ':git-info:' deleted ' %%B%F{red}✖%f%%b'
  zstyle ':git-info:' modified ' %%B%F{blue}✱%f%%b'
  zstyle ':git-info:' renamed ' %%B%F{magenta}➜%f%%b'
  zstyle ':git-info:' commit '%c'
  zstyle ':git-info:' stashed ' %%B%F{cyan}✭%f%%b'
  zstyle ':git-info:' unmerged ' %%B%F{yellow}═%f%%b'
  zstyle ':git-info:' untracked ' %%B%F{white}◼%f%%b'
  zstyle ':git-info:' prompt ' %F{blue}git%f%b%s'
  zstyle ':git-info:' rprompt '%A%B%S%a%d%m%r%U%u'

  PROMPT='%F{cyan}%1~%f${git_prompt_info} %(!.%B%F{red}#%f%b.%B%F{green}❯%f%b) '
  RPROMPT='%(?::%F{red}⏎%f)${git_rprompt_info}'
  SPROMPT='zsh: correct %F{red}%R%f to %F{green}%r%f [nyae]? '
}

prompt_sorin_setup "$@"